# Maintainer: Jesus E. <heckyel@riseup.net>

_pkgname=bencode
pkgbase=python-$_pkgname
pkgname=(python-$_pkgname tauthon-$_pkgname)
pkgver=1.0
pkgrel=1
pkgdesc="The BitTorrent bencode-module as a light-weight, standalone package"
url='https://pypi.python.org/pypi/BitTorrent-bencode'
arch=('i686' 'x86_64')
license=('BitTorrent-1.0')
makedepends=('python-setuptools' 'tauthon-setuptools')
source=("https://pypi.python.org/packages/source/b/bencode/$_pkgname-$pkgver.tar.gz")
sha512sums=('873bc7da16729a49033709f0663ef6d58076d0c5e1b31624e72a3eb35af7fa52af7ed42407b68995387ea9d6e2c009836f764c6a45b4e3b905d962110cf01ee8')

prepare() {
  cp -rf "$_pkgname-$pkgver" "$_pkgname-$pkgver-tauthon"
  cd "$srcdir/$_pkgname-$pkgver-tauthon"

  # tauthon fix
  for file in $(find . -name '*.py' -print); do
    sed -i 's_#!.*/usr/bin/python_#!/usr/bin/tauthon_' $file
    sed -i 's_#!.*/usr/bin/env.*python_#!/usr/bin/env tauthon_' $file
  done
}

package_python-bencode(){
  pkgdesc+=" for Python"
  depends=('python')

  cd "$srcdir/$_pkgname-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 PKG-INFO -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_tauthon-bencode(){
  pkgdesc+=" for Tauthon"
  depends=('tauthon')

  cd "$srcdir/$_pkgname-$pkgver"
  tauthon setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 PKG-INFO -t "$pkgdir/usr/share/licenses/$pkgname"
}