# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-beautifulsoup4
pkgname=('python-beautifulsoup4' 'tauthon-beautifulsoup4')
pkgver=4.9.3
pkgrel=2
arch=('any')
url='https://www.crummy.com/software/BeautifulSoup/index.html'
license=('Expat')
makedepends=('python-soupsieve' 'tauthon-soupsieve' 'python-setuptools' 'tauthon-setuptools')
source=("https://pypi.io/packages/source/b/beautifulsoup4/beautifulsoup4-$pkgver.tar.gz")
sha512sums=('e3cb6258bd7c51f12128fa8ee5948fb3566163ae233fac2dda21bab7772ab8dbb384d920b0ea138ef9921307b48f89cee3a9bf6111dfc8903d917ee7af365f34')

prepare() {
  cp -a beautifulsoup4-$pkgver{,-tauthon}
}

build() {
  cd "$srcdir"/beautifulsoup4-$pkgver
  python setup.py build

  cd "$srcdir"/beautifulsoup4-$pkgver-tauthon
  tauthon setup.py build
}

package_python-beautifulsoup4() {
  pkgdesc="A Python HTML/XML parser designed for quick turnaround projects like screen-scraping"
  depends=('python-soupsieve')
  optdepends=('python-chardet: to autodetect character encodings'
              'python-lxml: alternative HTML parser')

  cd beautifulsoup4-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_tauthon-beautifulsoup4() {
  pkgdesc="A Tauthon HTML/XML parser designed for quick turnaround projects like screen-scraping"
  depends=('tauthon-soupsieve')
  optdepends=('tauthon-chardet: to autodetect character encodings'
              'tauthon-lxml: alternative HTML parser')

  cd beautifulsoup4-$pkgver-tauthon
  tauthon setup.py install --root="$pkgdir" --optimize=1 --skip-build
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}