# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-bcrypt
pkgname=('python-bcrypt' 'tauthon-bcrypt')
pkgver=3.1.7
_debver=3.1.7
_debrel=4
pkgrel=1
pkgdesc='Modern password hashing for your software and your servers'
arch=('i686' 'x86_64')
url='https://github.com/pyca/bcrypt'
license=('Apache-2.0')
makedepends=('python-setuptools' 'tauthon-setuptools' 'python-cffi' 'tauthon-cffi'
             'python-six' 'tauthon-six' 'quilt')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/pyca/bcrypt/archive/$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/python-bcrypt/python-bcrypt_$_debver-$_debrel.debian.tar.xz")
sha512sums=('bfe487ac43aa5081a16c7f67787c2aec777a9c42f3f0f64d4dd238e6cf135e248e806a675ecdc5240066e2b5a31773f9c5dd939479e96ec25357e27bced01409'
            '04cbf69c18fc23d7164faf5641737943308b13d78a071447f007c3c32883e4f78a478117aa7498fbb7c8a301dee3ddebbd56b2436b7921dcb0f915122a602f0f')

prepare() {
  cd "$srcdir"/bcrypt-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  cp -a "$srcdir"/bcrypt-$pkgver{,-py2}
  export LC_CTYPE=en_US.UTF-8
}

build() {
  cd "$srcdir"/bcrypt-$pkgver
  python setup.py build

  cd "$srcdir"/bcrypt-$pkgver-py2
  tauthon setup.py build
}

package_python-bcrypt() {
  depends=('python-cffi' 'python-six')

  cd bcrypt-$pkgver
  python setup.py install --prefix=/usr --root="$pkgdir"
  install -d "$pkgdir"/usr/share/licenses/$pkgname
  install -m 644 "$srcdir"/bcrypt-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname
}

package_tauthon-bcrypt() {
  depends=('tauthon-cffi' 'tauthon-six')

  cd bcrypt-$pkgver-py2
  tauthon setup.py install --prefix=/usr --root="$pkgdir"
  install -d "$pkgdir"/usr/share/licenses/$pkgname
  install -m 644 "$srcdir"/bcrypt-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname
}