# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=python-asn1crypto
pkgname=('python-asn1crypto' 'tauthon-asn1crypto')
pkgver=1.4.0
pkgrel=2
arch=('any')
license=('Expat')
url="https://github.com/wbond/asn1crypto"
makedepends=('python-setuptools' 'tauthon-setuptools')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/wbond/asn1crypto/archive/$pkgver.tar.gz")
sha512sums=('989e4e0650252c29477d71263549b99f2c51c87f0768c20264b3de65f32edd8e7922e8af23bb1a7e29567a4ad8c4c5d596cdf7db3c766352c7f19d4f93361cd0')

prepare() {
  cp -a asn1crypto-$pkgver{,-tauthon}
}

build() {
  cd "$srcdir"/asn1crypto-$pkgver
  python setup.py build

  cd "$srcdir"/asn1crypto-$pkgver-tauthon
  tauthon setup.py build
}

package_python-asn1crypto() {
  pkgdesc="Python ASN.1 library with a focus on performance and a pythonic API"
  depends=('python')

  cd asn1crypto-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/python-asn1crypto/LICENSE
}

package_tauthon-asn1crypto() {
  pkgdesc="Tauthon ASN.1 library with a focus on performance and a pythonic API"
  depends=('tauthon')

  cd asn1crypto-$pkgver-tauthon
  tauthon setup.py install --root="$pkgdir" --optimize=1
  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/tauthon-asn1crypto/LICENSE
}