# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=profanity
pkgname=('profanity' 'profanity-gtk')
pkgver=0.14.0
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Console based XMPP client"
arch=('i686' 'x86_64')
url='https://profanity-im.github.io/'
license=('GPL-3')
makedepends=('curl' 'ncurses' 'expat' 'glib2' 'libotr' 'gpgme' 'python'
             'gtk' 'autoconf-archive' 'libgcrypt' 'libx11' 'libxss' 'libxcrypt' 'glibc'
             'freetype2' 'readline' 'libassuan' 'harfbuzz' 'pango' 'gdk-pixbuf2' 'atk'
             'cairo' 'libgpg-error' 'libstrophe' 'quilt')
source=("https://github.com/profanity-im/profanity/archive/${pkgver}/${pkgbase}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/profanity/profanity_${_debver}-${_debrel}~bpo12+1.debian.tar.xz")
sha512sums=('a1715e755f879e386fd1a9bf00ad241930b4010c38dc05e5bd6ba81ca0f2b8d3e6a564f9a7f839a6a2112513d7fc664d2f16ec3b844de7b7cf83cdd26d4f076d'
            'd34efaba9b6698afad2bdce224ae3d7e278a8d7eceb43ad48ada76887df62b7a1c9a1b9b9a6831cfcb5f322812eced3a39bdb6d5177bb05621db871aab3d16b1')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  mkdir -p m4
  autoreconf -fiv
  cp -a "${srcdir}"/${pkgname}-${pkgver}{,-gtk}
}

build() {
  echo "Building non-gtk variant..."
  (cd ${pkgname}-${pkgver}
    ./configure \
      --prefix=/usr \
      --disable-icons-and-clipboard \
      --without-xscreensaver \
      --disable-notifications \
      --enable-python-plugins \
      --enable-c-plugins \
      --enable-plugins \
      --enable-otr \
      --disable-omemo \
      --enable-pgp
    make
  )
  echo "Building gtk variant..."
  (cd ${pkgname}-${pkgver}-gtk
    ./configure \
      --prefix=/usr \
      --enable-icons-and-clipboard \
      --with-xscreensaver \
      --disable-notifications \
      --enable-python-plugins \
      --enable-c-plugins \
      --enable-plugins \
      --enable-otr \
      --disable-omemo \
      --enable-pgp
    make
  )
}

package_profanity() {
  depends=('curl' 'ncurses' 'expat' 'glib2' 'libotr'
           'libxcrypt' 'gpgme' 'python' 'libgcrypt' 'libstrophe'
           'glibc' 'readline' 'libassuan' 'libgpg-error')
  cd ${pkgbase}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t ${pkgdir}/usr/share/licenses/$pkgname
}

package_profanity-gtk() {
  pkgdesc+=" (gtk support)"
  depends=('curl' 'ncurses' 'expat' 'glib2' 'libotr' 'libxcrypt' 'gpgme' 'python'
           'libgcrypt' 'glibc' 'readline' 'libassuan' 'libgpg-error' 'libstrophe'
           'gtk' 'libxss' 'libx11' 'pango' 'freetype2' 'harfbuzz' 'gdk-pixbuf2' 'atk' 'cairo')
  provides=('profanity')
  conflicts=('profanity')
  cd ${pkgbase}-${pkgver}-gtk
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t ${pkgdir}/usr/share/licenses/$pkgname
}