# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=pidgin
pkgname=('pidgin' 'libpurple')
pkgver=2.14.1
_debver=$pkgver
_debrel=1
pkgrel=4
arch=('i686' 'x86_64')
url='https://pidgin.im/'
license=('GPL-2')
makedepends=('startup-notification' 'gtkspell2' 'libxss' 'nss' 'libsasl' 'libsm'
             'libidn' 'python' 'hicolor-icon-theme' 'tk' 'libnsl' 'ca-certificates'
             'intltool' 'gettext-tiny' 'libxcrypt' 'gtk2' 'perl' 'quilt')
source=(https://downloads.sourceforge.net/project/pidgin/Pidgin/$pkgver/$pkgname-$pkgver.tar.bz2{,.asc}
        https://deb.debian.org/debian/pool/main/p/pidgin/pidgin_${_debver}-${_debrel}.debian.tar.xz
        privacy.patch)
sha512sums=('6ce5c58f32fa680d7f67e37a42b0f77c8253018cee21df2895d52166d9eb6ecaf0458b1610adbd46f337d00e75933db7578c2f9808654bd22838ba5db0a13030'
            'SKIP'
            'e39a8d1848e9e4438ec5c1bda5d42ac614fbb20fd6a4b88554ea1a338919d785cb3783894c13e093676df6bb30e8dc4adb6254a80cae00432c57109ab4bb4b13'
            '36ffb6ca6e5feb86583af0679cb47a4a36cfdcf2e30dfa8b02fd316c4fc6daf7d5c008109a3af426f62f18d9af58122b9d61c32ee324d52309dbaef14247f453')
validpgpkeys=('40DE1DC7288FE3F50AB938C548F66AFFD9BDB729') # Gary Kramlich <grim@reaperworld.com>

prepare() {
  cd $pkgbase-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # additional fixes
  patch -Np1 -i $srcdir/privacy.patch
}

build() {
  cd $pkgbase-$pkgver

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --enable-cyrus-sasl \
    --enable-gtkspell \
    --disable-schemas-install \
    --disable-meanwhile \
    --disable-gnutls \
    --disable-doxygen \
    --disable-nm \
    --disable-avahi \
    --disable-dbus \
    --disable-farstream \
    --disable-vv \
    --disable-gstreamer \
    --disable-gstreamer-video \
    --disable-gstreamer-interfaces \
    --with-system-ssl-certs=/etc/ssl/certs \
    --with-dynamic-prpls=irc,jabber,silc,simple,zephyr
    make
}

package_pidgin(){
  pkgdesc="Multi-protocol instant messaging client"
  depends=('libpurple' 'startup-notification' 'gtkspell2' 'libxss' 'libsm' 'hicolor-icon-theme')
  optdepends=('aspell: for spelling correction'
              'pidgin-otr: for Off-the-Record Messaging support')

  cd $pkgbase-$pkgver

  # For linking
  make -C libpurple DESTDIR="$pkgdir" install-libLTLIBRARIES

  make -C pidgin DESTDIR="$pkgdir" install
  make -C doc DESTDIR="$pkgdir" install

  # Remove files that are packaged in libpurle
  make -C libpurple DESTDIR="$pkgdir" uninstall-libLTLIBRARIES

  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_libpurple(){
  pkgdesc="IM library extracted from Pidgin"
  depends=('libsasl' 'libidn' 'libnsl' 'nss' 'libxcrypt')
  optdepends=('ca-certificates: SSL CA certificates'
              'tk: Tcl/Tk scripting support')

  cd $pkgbase-$pkgver

  for _dir in libpurple share/sounds share/ca-certs m4macros po; do
    make -C "$_dir" DESTDIR="$pkgdir" install
  done

  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}