# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=picom
pkgver=8.2
_debver=8.2
_debrel=1
pkgrel=1
pkgdesc='X compositor that may fix tearing issues'
arch=('i686' 'x86_64')
url='https://github.com/yshui/picom'
license=('MPL-2.0')
provides=('compton')
makedepends=('asciidoc' 'mesa' 'meson' 'ninja' 'uthash' 'quilt')
depends=('hicolor-icon-theme' 'libconfig' 'libev' 'libgl' 'pcre' 'pixman'
         'xcb-util-image' 'xcb-util-renderutil')
backup=('etc/xdg/picom.conf')
optdepends=('python: For running picom-convgen.py'
            'xenocara-xwininfo: For picom-trans'
            'xenocara-xprop: For picom-trans')
source=("$pkgname-$pkgver.tar.gz::https://github.com/yshui/picom/archive/refs/tags/v${pkgver}.tar.gz"
	"https://deb.debian.org/debian/pool/main/p/picom/picom_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('bdc6675e73a211075ee0df2b056342cabb19ad27fd73586f5216886f503cd994536845eb866f371e07a8dc0404346c67b899a14830e9b7cbc9c01cbd782f36b1'
            '2d1c06ff09d3a83b0ed07035100ef8f385c0cab8c685a8ba6ea7fd41352823d2541bf202d53cd54129bdfadc76994d7cb09f4fe4607bda35415d7c9e7757c2d7')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  mkdir -p build
  hyperbola-meson build $pkgname-$pkgver -D b_ndebug=true -D with_docs=true -D dbus=false
  ninja -v -C build
}

package() {
  DESTDIR="$pkgdir" ninja -C build install

  # The config that comes with picom
  install -Dm644 $pkgname-$pkgver/picom.sample.conf "$pkgdir/etc/xdg/picom.conf"
  install -Dm644 $pkgname-$pkgver/picom.sample.conf "$pkgdir/usr/share/doc/picom/picom.conf.example"

  # Man pages and license file
  install -Dm644 build/man/picom.1 "$pkgdir/usr/share/man/man1/picom.1"
  install -Dm644 build/man/picom-trans.1 "$pkgdir/usr/share/man/man1/picom-trans.1"
  install -Dm644 $pkgname-$pkgver/LICENSES/MPL-2.0 -t "$pkgdir/usr/share/licenses/$pkgname"
}