# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-tk
pkgver=804.036
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="A graphical user interface toolkit for Perl"
arch=('i686' 'x86_64')
url='https://search.cpan.org/dist/Tk'
license=('GPL-2' 'custom:Tk' 'custom:Tix')
depends=('libpng' 'libjpeg-turbo' 'libx11' 'perl')
makedepends=('quilt')
options=('!emptydirs')
source=("https://www.cpan.org/authors/id/S/SR/SREZIC/Tk-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/p/perl-tk/perl-tk_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('7d8b82127a5fdbb2f0387f541af8844a09f1230f377b92d511ecb12e81bfd5ef56d4fe925cac064a798a96a003bb8465b6df37cff18a960f3631bb3a214cd812'
            '751bead14ee3b8eb81412b37e022a4a8a8d6db683074475e8b6155ef9de8da7c27de366ac3eeb9e543f3f1ef995fe933236a67f10ba4d4e43fea099b72c930fd')

prepare() {
  cd Tk-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd Tk-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  sed -E 's|(^OPTIMIZE.*)|\1 -Wno-incompatible-pointer-types -Wno-implicit-int|' -i Makefile
  make
}

package() {
  cd Tk-$pkgver
  make install DESTDIR="$pkgdir"

  # license
  install -Dm644 pTk/{license.terms,Tix.license} -t "$pkgdir"/usr/share/licenses/$pkgname
}