# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-timedate
pkgver=2.33
_debver=2.3300
_debrel=1
pkgrel=1
pkgdesc="Date formating subroutines"
arch=('any')
license=('GPL-1')
url="https://search.cpan.org/dist/TimeDate/"
depends=('perl')
makedepends=('quilt')
replaces=('timedate')
provides=('timedate')
options=('!emptydirs')
source=("https://www.cpan.org/authors/id/A/AT/ATOOMIC/TimeDate-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libt/libtimedate-perl/libtimedate-perl_$_debver-$_debrel.debian.tar.xz"
        'COPYING')
sha512sums=('a3a20a0d9439e68bf621c66fad0598e6257345727be79c87c7cc99994b3a58eb738787fedb720beb069e9758ad1347c15313f64411806dd0f4dfbcca5061c820'
            'd8c8e4529f4e093a0e802180dd706fe17fa814ab53793066dcf0c7e2f273b8c4e0c0d1f077bf3c72e46f50a091fef9c63262f7cb4037e1cb47ac126538cb80c4'
            'e239b539f2c46c1ae3da87c4983a0fda67dc8ae622d607b507b5c523af3bdf99e7bea8931e3a7c6007910bfe9e21a761e03e8203de95b5aceea425a97d0a84c9')

prepare() {
  cd TimeDate-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd TimeDate-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd TimeDate-$pkgver
  make test
}

package() {
  cd TimeDate-$pkgver
  make install DESTDIR="$pkgdir"
  install -Dm644 $srcdir/COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}