# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-test-requiresinternet
pkgver=0.05
pkgrel=2
pkgdesc="Easily test network connectivity"
arch=(any)
license=(GPL-1)
options=(!emptydirs)
depends=(perl)
url='https://search.mcpan.org/dist/Test-RequiresInternet'
source=("https://search.mcpan.org/CPAN/authors/id/M/MA/MALLEN/Test-RequiresInternet-$pkgver.tar.gz")
sha512sums=('572af3e6fdfb90df3a58ba6eaf571717b294a54fff4b3f597fd177f1eb91fb1c929cb808f8d219f692314a944cf41dc1afab41f5a0dd2185054c08fec69e66c3')
_distdir="Test-RequiresInternet-$pkgver"

build() {
  export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
    PERL_AUTOINSTALL=--skipdeps                            \
    PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='$pkgdir'"     \
    PERL_MB_OPT="--installdirs vendor --destdir '$pkgdir'" \
    MODULEBUILDRC=/dev/null

  cd $_distdir
  /usr/bin/perl Makefile.PL
  make
}

check() {
  cd $_distdir
  export PERL_MM_USE_DEFAULT=1 PERL5LIB=""
  make test
}

package() {
  cd $_distdir
  make install

  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete

  install -Dm644 LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}