# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-sdl
pkgver=2.548
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Simple DirectMedia Layer for Perl"
arch=('i686' 'x86_64')
license=('GPL-1' 'GPL-2')
url='https://metacpan.org/dist/SDL'
depends=('perl>=5.008' 'perl-alien-sdl>=1.446' 'perl-cpan>=1.92'
         'perl-file-sharedir>=1.00' 'perl-tie-simple'
         'sdl_net' 'sdl_ttf' 'sdl_image' 'sdl_mixer' 'sdl_gfx'
         'sdl_pango' 'smpeg')
makedepends=('perl-capture-tiny' 'perl-extutils-cbuilder'
             'perl-module-build>=0.40' 'perl-test-most>=0.21'
             'quilt')
options=('!emptydirs')
_cpan_author='FROGGS'
source=("https://cpan.metacpan.org/authors/id/${_cpan_author::1}/${_cpan_author::2}/$_cpan_author/SDL-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libs/libsdl-perl/libsdl-perl_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('bafc49dddb7e592861f822920915c73bf0c5eea3a6c567623b48a2332c7644caf1451e457545e6666adea5e314b23bcd85a3f3a52c770abfd498c0e4c0feae85'
            '9e6a7938ed50bc0d35bca55d2b30627e16651d927a4d1f3d7785e9aee26320a812b509a325016914acd8ebfe23f6f2f785e81a6c8cac84d6aa46ef00982f6126')

prepare() {
  cd SDL-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd SDL-$pkgver
  # Perl selects the proper CFLAGS set for binary modules
  unset CFLAGS
  # install module in vendor directories
  perl Build.PL installdirs=vendor
  perl Build
}

package() {
  cd SDL-$pkgver
  perl Build install destdir="$pkgdir"
  install -Dm644 COPYING debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}