# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-netaddr-ip
pkgver=4.079
_debver=4.079+dfsg
_debrel=1
pkgrel=1
pkgdesc="Perl module to manage IP addresses and subnets"
arch=('i686' 'x86_64')
url="https://search.cpan.org/dist/NetAddr-IP/"
license=('GPL-2')
depends=('perl')
makedepends=('quilt')
options=('!emptydirs')
source=(https://search.cpan.org/CPAN/authors/id/M/MI/MIKER/NetAddr-IP-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/libn/libnetaddr-ip-perl/libnetaddr-ip-perl_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('8ebc8ffb914cf72c041441f96de0e9c982eebdb8c26dbf15f885d0113b3634e4851d81f13f555c14d1fdf0ab95ae2ce880ed124e6c200e391adae3b1d6d3eb65'
            '1a4e593bd4916f9caf93dbc24a83d7684c638249b6e5de1c482198242dd085bd205a47b1c61bdc01427e3b75a87a9f3809b31b4ce53d0e2677a731c39efbce04')

prepare() {
  cd NetAddr-IP-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd NetAddr-IP-${pkgver}
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd NetAddr-IP-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 Copying -t "${pkgdir}/usr/share/licenses/$pkgname"
}