# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-net-server
pkgver=2.009
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc='Extensible, general Perl server engine'
arch=('any')
url="https://metacpan.org/release/Net-Server"
license=('GPL-1')
depends=('perl')
makedepends=('quilt')
options=('!emptydirs')
source=("https://search.cpan.org/CPAN/authors/id/R/RH/RHANDOM/Net-Server-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libn/libnet-server-perl/libnet-server-perl_$_debver-$_debrel.debian.tar.xz")
sha512sums=('36409f8d2478877c68cbfcbe9c08045b0c24a926b64f022faf3de8f4b4369ff417d5c41ff1e9800553c38da29c6d72ef301119c956cb26439f6b6366ff4b459c'
            '20bbb982a6ca9ba7c34fe1b483f23f3467d8d1097e01c8f2aaf4c5095837a1ae20499832ab5a6684b944d609a2d08cc9a87e6c83969365cbe3c04b26b47705fe')

prepare() {
  cd Net-Server-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd Net-Server-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd Net-Server-$pkgver
  make install DESTDIR="$pkgdir"
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}