# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-net-cidr-lite
_realname=Net-CIDR-Lite
pkgver=0.22
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Perl extension for merging IPv4 or IPv6 CIDR addresses"
arch=('any')
license=('GPL-1')
url='https://search.cpan.org/dist/Net-CIDR-Lite/'
depends=('perl')
makedepends=('quilt')
options=(!emptydirs)
source=("https://search.cpan.org/CPAN/authors/id/S/ST/STIGTSP/${_realname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libn/libnet-cidr-lite-perl/libnet-cidr-lite-perl_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('5d89c0b6d950e5cb4c7eb9639829d76a67373865f5582f61d3e384636b176ac08335a9210d05a53c54105fecfb8ec98ae115cba3d181aed3032370d50f3aec9f'
            'd90e86d7dcb9284cceed46f4c284a4cb8d865847beb54feae9f10a78c61f0a040aa90fc731e6f35fa1224fff45fa29eb6c9a2824d6128b63e7c98440ddae9fd1')

prepare() {
  cd ${_realname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${_realname}-${pkgver}
  # install module in vendor directories.
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd ${_realname}-${pkgver}
  make install DESTDIR="${pkgdir}"
  install -Dm644 debian/copyright -t "${pkgdir}/usr/share/licenses/${pkgname}"
}