# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-mime-charset
pkgver=1.012.2
pkgrel=1
pkgdesc="Charset Information for MIME"
arch=('any')
url='https://metacpan.org/release/MIME-Charset'
license=('GPL-2')
options=('!emptydirs')
depends=('perl')
checkdepends=('perl-test-pod')
source=("https://cpan.metacpan.org/authors/id/N/NE/NEZUMI/MIME-Charset-${pkgver}.tar.gz")
sha512sums=('2273bf0b86eb042e5aa8bcf958eefefde7dce6701eea5ae8c0fe9997e7d3e90d837a7791ade30f84536a15116175c796daee60da6625f409d214844dfedfde4d')

build() {
  cd "MIME-Charset-${pkgver}"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  perl Makefile.PL
  make
}

check() {
  cd "MIME-Charset-${pkgver}"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1
  make test
}

package() {
  cd "MIME-Charset-${pkgver}"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  make install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
  install -d -m755 "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim:set ts=2 sw=2 et: