# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-mailtools
pkgver=2.21
_debver=2.21
_debrel=1
pkgrel=1
pkgdesc="Various email related modules"
arch=('any')
url="https://metacpan.org/release/MailTools"
license=('GPL-1')
depends=('perl-timedate')
makedepends=('quilt')
options=('!emptydirs')
source=("https://search.cpan.org/CPAN/authors/id/M/MA/MARKOV/MailTools-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libm/libmailtools-perl/libmailtools-perl_$_debver-$_debrel.debian.tar.xz"
        'COPYING')
sha512sums=('70c7e5760691a1fc0a2812c48a632896db9bf719d3cb07a63c3a4456c5a365855c7f71c7436c84e5085374628f26ad31fcf13e74b3b7242911da59b7916065a0'
            'b29a897bcd7982945f8f08f1469f223ed406464b97952134fd969c8f02167a111f021e3b35384a7ad8aa3ab1d33e7bd83e96a2548e8a69abd4fb4450573f1da6'
            'e239b539f2c46c1ae3da87c4983a0fda67dc8ae622d607b507b5c523af3bdf99e7bea8931e3a7c6007910bfe9e21a761e03e8203de95b5aceea425a97d0a84c9')

prepare() {
  cd MailTools-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd MailTools-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd MailTools-$pkgver
  make test
}

package() {
  cd MailTools-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 ../COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}