# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-lockfile-simple
_realname=LockFile-Simple
pkgver=0.208
_debver=$pkgver
_debrel=1.1
pkgrel=1
pkgdesc="Perl module for simple advisory file locking"
arch=('any')
license=('GPL-2')
url='https://metacpan.org/dist/LockFile-Simple'
depends=('perl-log-agent' 'perl')
makedepends=('quilt')
options=(!emptydirs)
source=("https://cpan.metacpan.org/authors/id/S/SC/SCHWIGON/lockfile-simple/${_realname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libl/liblockfile-simple-perl/liblockfile-simple-perl_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('a1234d11cdb7bb98bd3d6c2504697187f2f7979c7acd7cfb0398f358f390af7b5eb7d834e83c83b0515199ac8d9a306d7fcdc96df04b0513f821887ad49fd67e'
            '40cf7c585bd91fca55e1a29aaa0e488fb2b7c795e51a334968845fa2915a3e86fe7e7f750573c123ed60c07ea9e2b32c6a7ac98b985e36cd9f13a48c1fdf3678')

prepare() {
  cd ${_realname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${_realname}-${pkgver}
  # install module in vendor directories.
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd ${_realname}-${pkgver}
  make install DESTDIR="$pkgdir"
  install -Dm644 debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}