# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-image-exiftool
_srcname=Image-ExifTool
pkgver=12.29
pkgrel=1
pkgdesc='Reader and rewriter of EXIF informations that supports raw files'
arch=('any')
url='https://search.cpan.org/perldoc?exiftool'
license=('GPL-1')
depends=('perl')
optdepends=('perl-archive-zip: Support for ZIP-files, including EPUB')
options=('!emptydirs')
source=(https://exiftool.org/${_srcname}-$pkgver.tar.gz
        LICENSE)
sha512sums=('a885848eee4322d9b03c6c03a428c44cd0607f256657652fd7ea2940999216c0b20f3e5170d33cc62da55ccc01ade7b4deb81b871eda70c73f598536b5fe0ff9'
            'e239b539f2c46c1ae3da87c4983a0fda67dc8ae622d607b507b5c523af3bdf99e7bea8931e3a7c6007910bfe9e21a761e03e8203de95b5aceea425a97d0a84c9')

build() {
  cd "${srcdir}/${_srcname}-${pkgver}"
  # install module in vendor directories.
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd "${srcdir}/${_srcname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -dm755 "$pkgdir/usr/share/$pkgname"
  cp -r fmt_files config_files arg_files "$pkgdir/usr/share/$pkgname"
  install -Dm644 "${srcdir}/LICENSE" -t "${pkgdir}/usr/share/licenses/$pkgname"
}