# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-glib-object-introspection
pkgver=0.049
pkgrel=2
pkgdesc="Dynamically create Perl language bindings"
arch=('i686' 'x86_64')
url="https://metacpan.org/release/Glib-Object-Introspection"
license=('LGPL-2.1')
makedepends=('gobject-introspection' 'perl-extutils-depends' 'perl-extutils-pkgconfig' 'perl-cairo-gobject')
depends=('glib-perl' 'gobject-introspection-runtime')
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/X/XA/XAOC/Glib-Object-Introspection-${pkgver}.tar.gz")
sha512sums=('fa927661dc761bfae9dba87e1e2d519b10c3aac4d6dcea37764972a0413a4f5025a12df640d66928b631c2933d4b0e6d02b559ea2c1eaa38fae6f7a9d98fe322')

build() {
  cd "Glib-Object-Introspection-${pkgver}"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  perl Makefile.PL
  make
}

check() {
  cd "Glib-Object-Introspection-${pkgver}"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1
  make test
}

package() {
  cd "Glib-Object-Introspection-${pkgver}"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  make pure_install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
  # Delete unuseful files
  find "${pkgdir}" -name '.packlist' -delete
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim:set ts=2 sw=2 et: