# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-file-desktopentry
pkgver=0.22
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Object to handle .desktop files"
arch=('any')
license=('GPL-1')
url='https://search.cpan.org/dist/File-DesktopEntry/'
depends=('perl-file-basedir' 'perl-uri')
makedepends=('quilt')
options=('!emptydirs')
source=("https://search.cpan.org/CPAN/authors/id/M/MI/MICHIELB/File-DesktopEntry-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libf/libfile-desktopentry-perl/libfile-desktopentry-perl_0.22-2.debian.tar.xz")
sha512sums=('f6a0f2a91c66ea3e5ebac1e66f82317c4109d8d3e2211b4e84cd870b9df07320c03ee0d026e89f788338a1c02152c77e36402684da4f5a7093eb3ac21ff584a7'
            'f3f18248b03b8486427cbda8b55cf2cd9abc12e7acdd07ded6b8f5a294b8ee98a219f84ffcd3758e99e445526b1668f422743000701caec484c551492a05a1c3')

prepare() {
  cd File-DesktopEntry-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd File-DesktopEntry-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd File-DesktopEntry-$pkgver
  make DESTDIR="${pkgdir}" install
  install -Dm644 debian/copyright -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}