# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-anyevent
pkgver=7.17
_debver=$pkgver
_debrel=2
pkgrel=2
pkgdesc="The DBI of event loop programming"
arch=('any')
url='https://metacpan.org/release/AnyEvent'
license=('GPL-1')
depends=('perl')
makedepends=('quilt')
optdepends=('perl-guard: to speed up guards'
            'perl-json: send or receive JSON with AnyEvent::Handle'
            'perl-json-xs: send or receive JSON with AnyEvent::Handle'
            'perl-net-ssleay: TLS/SSL connections with AnyEvent::Handle')
options=('!emptydirs')
source=("https://search.cpan.org/CPAN/authors/id/M/ML/MLEHMANN/AnyEvent-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/liba/libanyevent-perl/libanyevent-perl_${_debver}0-${_debrel}.debian.tar.xz")
sha512sums=('c553cce80fa14e2f91031c569d1c30acf470871ddd1c122fa3dd36cd1ba5b7002e7ba1dea4c950d889c7c661b81042dd97975e195a5325190ad644babff81e0a'
            'e3d43b9210cb92c6ed50ce9232140fd3c54607e7a38bdeb244bb37d03e51971f974e829e949bb4b6b38c839bec9b59c0bac4e78e607c40692935f70621c99dd2')

prepare() {
  cd AnyEvent-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd AnyEvent-$pkgver
  PERL_CANARY_STABILITY_NOPROMPT=1 \
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd AnyEvent-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
}