# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=pbzip2
pkgver=1.1.13
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Parallel implementation of the bzip2 block-sorting file compressor"
arch=('i686' 'x86_64')
url="http://compression.ca/pbzip2/"
license=('Original-BSD')
depends=('bzip2' 'gcc-libs')
makedepends=('quilt')
source=(https://launchpad.net/$pkgname/1.1/$pkgver/+download/$pkgname-$pkgver.tar.gz{,.asc}
        https://deb.debian.org/debian/pool/main/p/pbzip2/pbzip2_$_debver-$_debrel.debian.tar.xz)
sha512sums=('a150e476a85b2ae71c244561380f8f113072ef712173afaa0bdace5845d5f81a15b135258cb01376156b69a5085b02b7ab866cfab5713aa773b251b203c087b8'
            'SKIP'
            'd4daeb8d0fb8d78245e93b99bc151b71fbfbdc1fa82b9556624cf901cd8c7410f0e5bae368f7fc734a20c380bc923cadf58feb28af24a91f8f856b3770914747')
validpgpkeys=('F3D99FF0F0AA96A659AD61A9D332F1B09A0D9836')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # Use our CXXFLAGS and LDFLAGS
  sed -i '/^\(CXX\|LD\)FLAGS =/d' Makefile
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make PREFIX=/usr DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}