# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=parcellite
pkgver=1.2.1
pkgrel=2
pkgdesc="Lightweight GTK+ clipboard manager"
arch=('i686' 'x86_64')
url='https://parcellite.sourceforge.net/'
license=('GPL-3')
depends=('gtk2' 'xdotool')
makedepends=('intltool' 'gettext-tiny')
source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz"
	"fix-crash.patch"
	"remove-unused-des-and-add-missing-keywords.patch")
sha512sums=('14b513e760e205666e00893dffb75ef3d42994aaeca3238b5adbed4af7495a7ed67cfabdcb163024fb9b0a7e832599bb31c54201217ac3fca88e0a4a22deb53d'
	    '3cfbf5e22ff33d4c33696fb2a8e4c24b91ded0a36b30188e47f56532e315184eed69e66f3dc4dd9cd1dcaa1310d9343e79d19238012acf76fb36418766e007c9'
	    'dd7d8f99c6154d6ed159d425060bc25573fc67750e2e581217ac1042a6b780dfc22c4bda195c5456a46823eda6f49491d72a5d69f7b72ebc074a14b4a5b5f9da')

prepare() {
  cd ${pkgname}-${pkgver}

  # apply patch fixing crash on the preferences dialogue
  patch --verbose -p1 -i ../fix-crash.patch

  # apply patch removing other desktop environments that are unused
  # and adding missing keywords in the application shortcut
  patch --verbose -p1 -i ../remove-unused-des-and-add-missing-keywords.patch
  sed -i '8d' data/${pkgname}-startup.desktop.in
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install
  install -Dvm644 COPYING -t ${pkgdir}/usr/share/licenses/${pkgname}
}