# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=nyx
pkgver=2.1.0
_debver=$pkgver
_debrel=2.2
pkgrel=3
pkgdesc="Command-line status monitor for tor"
url='https://nyx.torproject.org/'
arch=('any')
license=('GPL-3')
depends=('python' 'python-stem' 'procps-ng' 'lsof')
makedepends=('python-setuptools' 'quilt')
optdepends=('tor: tor-server to talk to')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/n/nyx/nyx_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/nyx/nyx_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('d91322219ba9b2a24eae8bb148b72f0f8cd9dd1f00b2fd64ed44101387fef0df52825eb169ddb6f350a95d1f4c760977af0aa3a0fe17be9c1fb5df32b7dfbb5c'
            '4495cf36de5e6d4d649c2bd6f35e967663af0df8a26496eedf083e89383844f2e83a8e0cb578e94089b0ab1c3d444b5886913a867bffabc25b565f2fdc6182c9')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # remove tests requiring full terminal
  rm -r test/{panel,{popups,subwindow,installation}.py}

  # make test exit on error
  sed -E 's|(test_runner.run\(tests\))|__import__("sys").exit(0 if \1.wasSuccessful() else 1)|' -i run_tests.py
}

build() {
  cd ${pkgname}-${pkgver}
  python setup.py build
}

package() {
  cd ${pkgname}-${pkgver}
  python setup.py install --optimize=1 --root="${pkgdir}" --skip-build
  install -Dm 644 nyx.1 -t "${pkgdir}/usr/share/man/man1"
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}