# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=numlockx
pkgver=1.2
_debver=1.2
_debrel=8
pkgrel=4
pkgdesc='Turns on the numlock key in X11.'
arch=('i686' 'x86_64')
url='https://github.com/rg3/numlockx'
license=('Expat')
depends=('libxtst')
makedepends=('quilt')
source=(https://github.com/rg3/numlockx/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/n/numlockx/numlockx_$_debver-$_debrel.debian.tar.xz)
sha512sums=('efaaa67e8b2723cb1e8461dde664f1f8e9b21f34edfe2e1135a6b756fa2843aed1a386f2f9d70bd62ddae9aedfeeff856a18da8b542f2cff440f93b38e5a853e'
            'aa849a9f89d88137c5066144f69be90c45003031b2d6fb59c48c6265b71a4d519d51bc8c964a832fa4fb12e83442d435235765f2a6b622947e2107604c7a4fc9')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr x_includes=/usr/include/X11 x_libraries=/usr/lib
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make prefix="${pkgdir}/usr" install

  # Install license
  install -Dm0644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}