# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=nsxiv
pkgver=31
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Neo (or New or Not) Simple (or Small or Suckless) X Image Viewer"
arch=('i686' 'x86_64')
license=('GPL-2')
url='https://nsxiv.codeberg.page/'
provides=('sxiv')
conflicts=('sxiv')
replaces=('sxiv')
depends=('imlib2' 'libx11' 'libxft' 'fontconfig' 'freetype2' 'libexif' 'hicolor-icon-theme')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://codeberg.org/nsxiv/nsxiv/archive/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/nsxiv/nsxiv_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('64139d3a0c74a96eb01f21689a5d9af64012dd02d85ab6984eb4881218eb095f05134bbd91da5ff6fe8246782121a90f6b3524f5a51296de0dfbe852f600cfaa'
            'd2001a12ac676fe069aca233db1d50c777dddcd9a0781e15324b86a9000a5eb0fdcbb26d8e494f3bd8764d06f28ae8975f52bad514890daa8f974afad653c2ba')

prepare() {
  cd "$pkgname"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  [ ! -f config.h ] && cp config.def.h config.h

  # make install currently also runs make all
  # see https://codeberg.org/nsxiv/nsxiv-record/issues/237
  sed -i -e '/^install: / s|: all|:|' Makefile
}

build() {
  make -C "$pkgname" HAVE_LIBGIF=0 HAVE_LIBWEBP=0 HAVE_INOTIFY=0 HAVE_LIBFONT=1 HAVE_LIBEXIF=1
}

package() {
  make -C "$pkgname" PREFIX=/usr DESTDIR="$pkgdir" install-all
  install -Dm644 "$srcdir/$pkgname/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname"
}