# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=notion
pkgver=4.0.2
_debver=$pkgver
_debrel=6
pkgrel=2
pkgdesc="Tabbed and tiling window manager"
arch=('i686' 'x86_64')
url='http://notion.sourceforge.net/'
license=('LGPL-2.1')
depends=('glib2' 'lua' 'libxext' 'libsm' 'libxinerama' 'libxrandr')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/raboof/notion/archive/refs/tags/${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/notion/notion_${_debver}+dfsg-${_debrel}.debian.tar.xz")
sha512sums=('ac764d7f754407b315660e33eb6a561f9c003c353e8710df25858c461b8e1b6a1ecc1f5f9091cf85195ca4b146936c586287c47ffe98f37a89889034c1b932a7'
            '28664928dda05ef8b382434e728bcca1b152de403b2a9d5617618addbeff65fbdbf9905e9c71690f7ba9d55d75eca95d0319de45c4713edafe366babbe9d033a')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/0001-201_build-config.patch || true
    rm -v debian/patches/0002-206_use-x-terminal-emulator.patch || true
    rm -v debian/patches/0003-209_use-etc-default.patch || true
    rm -v debian/patches/0004-210_use-cfg_debian_ext.patch || true
    rm -v debian/patches/0005-211_add-debian-menu.patch || true

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver

  export PREFIX=/usr
  export ETCDIR=/etc/notion
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir/" install
  cp -R contrib "$pkgdir/usr/share/"
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}