# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=nnn
pkgver=5.1
pkgrel=1
pkgdesc="Fast terminal file manager"
url='https://github.com/jarun/nnn'
arch=('i686' 'x86_64')
license=('Expat' 'Simplified-BSD')
depends=('bash' 'sed')
optdepends=('libarchive: for more archive formats'
            'zip: for zip archive format'
            'unzip: for zip archive format'
            'sshfs: mount remotes'
            'fuse2: unmount remotes'
            'xdg-utils: desktop opener')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/jarun/nnn/archive/v${pkgver}.tar.gz")
sha512sums=('6b20f14a937c232b072c90e81d49dc2d4c422918d7a5fdca6502dbc0c75ec73850f31fa9eccbc31b4773e700b255b4800baa5fe2f920b3c4c430151b53d4c33f')

prepare() {
  sed -i 's/install: all/install:/' "${pkgname}-${pkgver}/Makefile"
}

build() {
  cd "${pkgname}-${pkgver}"
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" PREFIX=/usr install
  make DESTDIR="${pkgdir}" PREFIX=/usr install-desktop

  install -Dm644 misc/auto-completion/bash/nnn-completion.bash "${pkgdir}/usr/share/bash-completion/completions/nnn"
  install -Dm644 misc/auto-completion/zsh/_nnn "${pkgdir}/usr/share/zsh/site-functions/_nnn"

  install -Dm644 -t "${pkgdir}/usr/share/nnn/quitcd/" misc/quitcd/*

  # handle plugins
  cp -a plugins "${pkgdir}/usr/share/nnn/plugins/"
  rm "${pkgdir}/usr/share/nnn/plugins/"{boom,getplugs,gsconnect,imgur,imgresize,kdeconnect,moclyrics,mtpmount,upload}
  rm "${pkgdir}/usr/share/nnn/quitcd/"quitcd.fish

  install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" LICENSE
}