# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=nml
pkgver=0.7.4
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="OpenTTD newgrf meta language compiler"
arch=('i686' 'x86_64')
url='https://github.com/OpenTTD/nml'
license=('GPL-2')
depends=('python-ply' 'python-pillow' 'python-setuptools')
makedepends=('quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/n/nml/nml_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/nml/nml_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('78a0961db3a56684fbc999f69bc5e02b9f002ba7b7a2afd39c7d4c9695b3306339ee55c4b9d711d85ca7c4c0e4d53abc71c9e0720904d44a0c388a793a28fc4b'
            'b9328faabcd5d305a32dc5521f4f8d83d81d58eb2d260102d9531f378356b974be67b12e426d0d5316becb10d80fb61f4456db11da1975152312c5c405c5eff2')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${pkgver}"
  python setup.py build
}

package() {
  cd "${pkgname}-${pkgver}"
  python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}