# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=neomutt
pkgver=20220429
_debver=$pkgver
_debrel=4.1
pkgrel=1
pkgdesc="A version of mutt with added features"
arch=('i686' 'x86_64')
url='https://neomutt.org/'
license=('GPL-2')
depends=('glibc' 'gpgme' 'lua' 'notmuch-runtime' 'krb5' 'gnutls' 'sqlite'
         'libsasl' 'ncurses' 'libidn2' 'lmdb' 'gdbm' 'kyotocabinet'
         'lz4' 'zlib' 'db')
makedepends=('gnupg-stable' 'libxslt' 'docbook-xsl' 'quilt')
optdepends=('python: keybase.py'
            'perl: smime_keys'
            'ca-certificates: default CA certificates')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/neomutt/neomutt/archive/refs/tags/${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/neomutt/neomutt_${_debver}+dfsg1-${_debrel}.debian.tar.xz")
sha512sums=('ce151cabe9fe0c45f379dd7a71790f600faa9283c79a486c1421b5fe3b19b7f12d71dc36ec330e1b28b26ed83bf4c47b656ca823c484105ea3f80ef9166e7f0b'
            'f1f462a6dc2169a18d32bcad74fe6b7a7fd00ef11816a885500646896a7d797715f8f678cbd54d1ff0582718092e86bfd645eb40ad9d0a2deb47bb2b3bfbdaf9')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/debian-specific/document_debian_defaults.patch || true
    rm -v debian/patches/debian-specific/neomuttrc.patch || true
    rm -v debian/patches/debian-specific/use_usr_bin_editor.patch || true

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --gpgme \
    --sqlite \
    --autocrypt \
    --lua \
    --notmuch \
    --gss \
    --gnutls \
    --sasl \
    --with-idn2=/usr \
    --idn2 \
    --bdb \
    --lmdb \
    --gdbm \
    --lz4 \
    --zlib \
    --kyotocabinet \
    --disable-idn \
    --disable-zstd
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENSE.md -t "$pkgdir/usr/share/licenses/$pkgname"
}