# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=nedit
pkgver=5.7
_debver=$pkgver
_debrel=3
pkgrel=2
pkgdesc="A free software text editor for programmers and general users"
arch=('i686' 'x86_64')
url='https://sourceforge.net/projects/nedit/'
license=('GPL-2')
depends=('openmotif')
makedepends=('quilt')
options=('!makeflags')
source=("https://sourceforge.net/projects/nedit/files/nedit-source/${pkgname}-${pkgver}-src.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/${pkgname}/${pkgname}_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('cf242d2f8eea4c78649dbeb741f545a3dc8ffaf5bb36239794a4b2635420e5445fa1c77472add79c05ec081d71a0b9df4431f48db365a71692e43869fd4e7932'
            '6573ce8e5f610ed8482fe48e9c69fdb768365c9e0c246b15aee114608f0984c3ca4c782de71dd1e33746449b660bb4fa656dea995c557790638652c06a4f262f')

prepare() {
  cd ${pkgname}-${pkgver/a/}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  sed -i 's|"/bin/csh"|"/bin/sh"|' source/preferences.c
}

build() {
  cd ${pkgname}-${pkgver/a/}
  make CFLAGS+="${CFLAGS} -DBUILD_UNTESTED_NEDIT" linux docs
}

package() {
  cd ${pkgname}-${pkgver/a/}
  install -Dm755 source/$pkgname "${pkgdir}/usr/bin/$pkgname"
  install -Dm755 source/nc "${pkgdir}/usr/bin/$pkgname-client"
  install -Dm644 doc/$pkgname.man "${pkgdir}/usr/share/man/man1/$pkgname.1"
  install -Dm644 doc/nc.man "${pkgdir}/usr/share/man/man1/$pkgname-client.1"
  install -Dm644 doc/$pkgname.html -t "${pkgdir}/usr/share/doc/$pkgname"
  install -Dm644 debian/$pkgname.desktop -t "${pkgdir}/usr/share/applications"
  install -Dm644 COPYRIGHT -t "${pkgdir}/usr/share/licenses/$pkgname"
}