# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mpg123
pkgver=1.26.4
_debver=1.26.4
_debrel=1
pkgrel=1
pkgdesc='Console based real time MPEG Audio Player for Layer 1, 2 and 3'
url="https://sourceforge.net/projects/mpg123"
arch=('i686' 'x86_64')
license=('LGPL-2.1')
depends=('libltdl' 'alsa-lib')
makedepends=('sdl2' 'jack' 'libsndio' 'quilt')
optdepends=('sdl2: for sdl2 audio support'
            'jack: for jack audio support'
            'sndio: for sndio audio support'
            'perl: for conplay')
source=(https://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.bz2{,.sig}
        https://deb.debian.org/debian/pool/main/m/mpg123/mpg123_$_debver-$_debrel.debian.tar.xz)
sha512sums=('425162227aafb99b8723428fe9bd403739a2dd68828b86a2cff7f9928a9f0ab3f67420e56c0abe7c9deeb94bce6c6acd59acaa0606ce24c01716465640564785'
            'SKIP'
            '9f932bda4271ab859e9df075acb0000d29e3773f2368a155717da1ff4d3236199db3a012ec8278de3be3b9631ff73af13bf0e47a645ba78a99971e82a0f610f0')
validpgpkeys=('D021FF8ECF4BE09719D61A27231C4CBC60D5CAFE')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --enable-int-quality \
    --with-module-suffix=.so \
    --with-audio="alsa oss sdl jack sndio"
  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 755 scripts/conplay "${pkgdir}/usr/bin/conplay"
  install -Dm 644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}