# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mmv
pkgver=1.01b
_debver=$pkgver
_debrel=19
pkgrel=2
pkgdesc="Move/Copy/Append/Link multiple files"
license=('GPL-2')
makedepends=('quilt')
arch=('i686' 'x86_64')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/m/mmv/mmv_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/m/mmv/mmv_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('4bf4e096b930bdde225ba5de761e968af3aed33dc13194b1a1a79078cd27e158b04aae131b5167cf5f844e35355d67359443cd598db22da15a5af06752438917'
            '86fb93180a8645a40f45d0b9331693f6a86fbe1a378857350c9573e45261e008ab2154836df09a4f569bc35b6601d0317a0f1f1a901530e26e391c3a25c666f5')

prepare() {
  mv "${pkgname}-${pkgver}.orig" "$pkgname-$pkgver"
  cd "${srcdir}/$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  sed -i -e "s/LDFLAGS.\s=-s -N/LDFLAGS	=-s/g" Makefile
  sed -i 's!/usr/man!/usr/share/man!' Makefile
}

build() {
  cd "${srcdir}/$pkgname-$pkgver"
  make
}

package(){
  cd "${srcdir}/$pkgname-$pkgver"
  mkdir -p "${pkgdir}/usr/bin"
  mkdir -p "${pkgdir}/usr/share/man/man1"
  make DESTDIR="${pkgdir}" install
  chmod 644 "${pkgdir}/usr/share/man/man1/mmv.1"

  cd "${pkgdir}/usr/bin"
  ln -s mmv mcp
  ln -s mmv mad
  ln -s mmv mln

  cd "${pkgdir}/usr/share/man/man1/"
  ln -s mmv.1 mcp.1
  ln -s mmv.1 mad.1
  ln -s mmv.1 mln.1

  install -Dm644 "${srcdir}/$pkgname-$pkgver/debian/copyright" -t "$pkgdir/usr/share/licenses/$pkgname"
}