# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mlmmj
pkgver=1.5.0
_pkgver=1_5_0
pkgrel=1
pkgdesc="Simple, free and libre mailing list manager"
arch=('i686' 'x86_64')
url='https://codeberg.org/mlmmj/mlmmj'
license=('Expat')
depends=('bash' 'glibc' 'smtp-server')
optdepends=('perl: for running contributed scripts'
            'python: for running contributed scripts')
source=("https://codeberg.org/mlmmj/mlmmj/releases/download/RELEASE_$_pkgver/$pkgname-$pkgver.tar.xz")
sha512sums=('8084854bfebbff22b57e5cdcb31371500397694b3179f27efe46e80f2322b9bedd7e22975fa0886a16e9fd1a306d699b643236648c8ede762d5bd971fae3852d')

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --disable-tests
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  install -Dm644 ChangeLog FAQ README.* TODO TUNABLES.md UPGRADE -t "$pkgdir/usr/share/doc/$pkgname"
  cp -fa contrib "$pkgdir/usr/share/doc/$pkgname/"

  # remove unwanted data
  rm -rf "$pkgdir/usr/share/doc/$pkgname/contrib/web/"php-{admin,moderation,user}

  install -Dm644 COPYING LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}