# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=miniupnpc
pkgname=(miniupnpc python-miniupnpc)
pkgver=2.2.1
_debver=2.2.1
_debrel=1
pkgrel=1
pkgdesc='Small UPnP client library/tool to access Internet Gateway Devices'
url='https://miniupnp.tuxfamily.org/'
arch=('i686' 'x86_64')
license=('Modified-BSD')
makedepends=('sh' 'glibc' 'lsb-release' 'python' 'python-setuptools' 'quilt')
source=(https://miniupnp.tuxfamily.org/files/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/m/miniupnpc/miniupnpc_$_debver-$_debrel.debian.tar.xz)
sha512sums=('62fc0098890980028199dd16e87b13ce23e78b2cc996433799792dc2a4fa9b5e230139593bde5c721f649c14fcee2e4d8a0558976c5506c21ff26deff6c7c907'
            'c3895fe2e13e8a19552d4d6aa1723785ec191c49258ceb0caa03bbbbb6b684190233c3ab1c993756650395bc812800366e1bf5f93a1205fd67d4d689f4fdd83d')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  make
  python setup.py build
}

check() {
  cd ${pkgname}-${pkgver}
  make test
}

package_miniupnpc() {
  depends=('sh' 'glibc')

  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 man3/miniupnpc.3 -t "${pkgdir}/usr/share/man/man3"
  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_python-miniupnpc() {
  pkgdesc='Python bindings for miniupnpc'
  depends=('python' 'glibc')

  cd ${pkgbase}-${pkgver}
  python setup.py install --optimize=1 --skip-build --root="$pkgdir"
  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}