# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=meson
pkgver=0.56.2
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="High productivity build system"
url='https://mesonbuild.com/'
arch=('any')
license=('Apache-2.0')
depends=('python-setuptools' 'ninja')
makedepends=('quilt')
source=("https://github.com/mesonbuild/meson/releases/download/${pkgver}/meson-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/m/meson/meson_${_debver}-${_debrel}.debian.tar.xz"
        "hyperbola-meson")
sha512sums=('3b6cc5cae31d756b251ecde3483d3710bceff50cfd03ef6cf6f939d9e599998e61fcb03a2ee09d6a6f9bfa2198f43e7f20447359de3bff1055febcf03e82e514'
            '1a9ddb7d8e78a6b12e2e842f99afafd4b1f0c25abe2f8d3635c4cb4aba4480c0fb46f019363d62bc9ac2a6f71c8320daa21b2281b866b47121c8b9a4960e98de'
            '71da41c3d16d14f0aabda58ece4d0e235191f086cc8a2e2ad73a405cf4402335930949b4103cf728b21c8a5fa71248f461ca064f012f6598affba4aec4a4d2ab')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  python setup.py build
}

package() {
  cd ${pkgname}-${pkgver}
  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build

  install -d "${pkgdir}/usr/share/vim/vimfiles"
  cp -rt "${pkgdir}/usr/share/vim/vimfiles" data/syntax-highlighting/vim/*

  install -Dt "${pkgdir}/usr/share/emacs/site-lisp" -m644 data/syntax-highlighting/emacs/*
  install -Dt "${pkgdir}/usr/share/zsh/site-functions" -m644 data/shell-completions/zsh/*

  # Hyperbola packaging helper
  install -D ../hyperbola-meson -t "${pkgdir}/usr/bin"

  # install license
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}