# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=meld
pkgver=3.20.2
_debver=$pkgver
_debrel=2
pkgrel=3
pkgdesc="Compare files, directories and working copies"
url='https://meldmerge.org/'
license=('GPL-2')
arch=('any')
depends=('python-pygobject' 'python-pycairo' 'gtksourceview3' 'gsettings-desktop-schemas')
makedepends=('intltool' 'yelp-tools' 'quilt')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/m/meld/meld_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/m/meld/meld_$_debver-$_debrel.debian.tar.xz")
sha512sums=('9c9074cb879e3574eb9a1025eb1212771419ab0d8e92bf8a99f38e70ca583ff5c8cbeaccb87b414e6ff73a61afa08e10742991d574b810cc90e8c4a5ac82ddaa'
            'd6bc340b582047f615b752250c832f94fc790ae6443908feb038911524e13d4d56cb4502f2f846cb6fe894d52f5b55da5635b692797b7a0c54698694caef2ba4')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver

  python setup.py build
}

package() {
  cd $pkgname-$pkgver

  # using --skip-build breaks install
  python setup.py --no-update-icon-cache --no-compile-schemas \
    install --prefix=/usr --root="$pkgdir" --optimize=1

  # license
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}