# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mcpp
pkgver=2.7.2
_debver=$pkgver
_debrel=5
pkgrel=1
pkgdesc="Alternative C/C++ preprocessor"
arch=('i686' 'x86_64')
license=('Simplified-BSD')
url='http://mcpp.sourceforge.net'
depends=('glibc')
makedepends=('quilt')
source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/m/mcpp/mcpp_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('1ca885cb13fdb684de9d0595a9215b52f48a93a69077d82cdcacafe40d9a61fb77b00a3ff2b8890e7bc0a0fcc0c8d70d4093c00c280351cd4459aba67c573235'
            '08509945048ccc4525ecd61d3f901a4d81fe73c1db84c26b76664d5127970af45662a168b99836b58467afc7202a1a20e0dfe8954a87e4cd1368f2136d7955be')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"
  ./configure \
    --prefix=/usr \
    --enable-mcpplib \
    --disable-static
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="${pkgdir}" install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}