# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=lxrandr
pkgname=(lxrandr-gtk2 lxrandr)
pkgver=0.3.2
pkgrel=1
pkgdesc='Monitor configuration tool'
arch=('i686' 'x86_64')
license=('GPL-2')
url='https://lxde.org/'
makedepends=('gtk2' 'gtk' 'intltool' 'gettext-tiny')
source=("https://downloads.sourceforge.net/lxde/$pkgbase-$pkgver.tar.xz")
sha512sums=('9f00f885e4af3544d9bf8a7581d5b9e3049c1fac174c119dda8c85f2f94aa7be241b6e06e5fe86596a0fb65a38bfe1983ced91c064339a60b19f506ed337ee4f')

build() {
  # GTK+ 2 version
  [ -d gtk2 ] || cp -r $pkgbase-$pkgver gtk2
  cd gtk2
  ./configure --sysconfdir=/etc --prefix=/usr
  make

  cd "$srcdir"
  # GTK+ 3 version
  [ -d gtk3 ] || cp -r $pkgbase-$pkgver gtk3
  cd gtk3
  ./configure --sysconfdir=/etc --prefix=/usr --enable-gtk3
  make
}

package_lxrandr-gtk2() {
  depends=('gtk2' 'xenocara-xrandr')
  conflicts=('lxrandr')

  cd gtk2
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}

package_lxrandr() {
  pkgdesc+=' (GTK+ 3 version)'
  depends=('gtk' 'xenocara-xrandr')
  conflicts=('lxrandr-gtk2')

  cd gtk3
  make DESTDIR="$pkgdir" install

  # Ignore package by AppStream to avoid duplicated IDs
  echo 'X-AppStream-Ignore=true' >> "$pkgdir/usr/share/applications/$pkgbase.desktop"

  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}