# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=lxdm
pkgname=('lxdm-gtk2' 'lxdm')
pkgver=0.5.3
pkgrel=2
pkgdesc="Lightweight X11 Display Manager"
arch=('i686' 'x86_64')
url='https://lxde.org/'
license=('GPL-2')
makedepends=('intltool' 'iso-codes' 'gtk2' 'gtk' 'xenocara-server' 'gettext-tiny')
optdepends=('iso-codes: for showing language names in language chooser')
backup=('etc/lxdm/lxdm.conf'
        'etc/lxdm/Xsession'
        'etc/lxdm/PreLogin'
        'etc/lxdm/LoginReady'
        'etc/lxdm/PostLogin'
        'etc/lxdm/PostLogout'
        'etc/lxdm/PreReboot'
        'etc/lxdm/PreShutdown')
source=("https://downloads.sourceforge.net/lxde/${pkgbase}-${pkgver}.tar.xz"
        "set-path.patch"
        "git-fixes.patch"
        "lxdm.initd"
        "lxdm.run")
sha512sums=('0e3539c595a71cb850c1756dd075b8d477a4e111a4167714057cac06650e9587f338f797f14122e7b2a2f4ad35b38cd7172b83e996758abeeaf0146d65bbc26f'
            '31458f9cbf2eefa863ea7b8b26778b8738311a16ff0e41d21e431dca94165fa0dab3274679504d4d2b964ce473ce2de5a692376393abeba000e19ae675813bf8'
            '3ac6601dafe36cfe95a7895b3e138d184b2098a58b2e93fbb168e91cd51ffef5cbc55403138b326f68b85f8d4bb3c303dc734378dca808432edf5cf85e93afd5'
            '918a51293384f0aae69afb0fb1d25a1120d663cc7473b0796aaaf727a989290a1730c2415d90d04d7ad7d3691ca1d2ca77d9754ac6f5f0aa9574581841b51293'
            '35b640d1cc9d745076d0d25cf3dda0dbe1ffc7d8a0a10a98637e102bf6fe61a6d3992d406512d63e520ea45186e3e66d5ffa232fda4d41ab3a5c688de33a3c2d')

prepare(){
  cd $pkgbase-$pkgver

  # don't overwrite PATH if already defined
  patch -Np1 -i $srcdir/set-path.patch

  # apply fixes from git
  patch -Np1 -i $srcdir/git-fixes.patch

  autoreconf -vfi
}

build() {
  # GTK+ 2 version
  [ -d gtk2 ] || cp -r $pkgbase-$pkgver gtk2
  cd gtk2
  ./configure \
    --prefix=/usr \
    --libexecdir=/usr/lib/lxdm \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --without-pam \
    --with-xconn=xcb
  make

  cd "$srcdir"
  # GTK+ 3 version
  [ -d gtk3 ] || cp -r $pkgbase-$pkgver gtk3
  cd gtk3
  ./configure \
    --prefix=/usr \
    --libexecdir=/usr/lib/lxdm \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --enable-gtk3 \
    --without-pam \
    --with-xconn=xcb
  make
}

package_lxdm-gtk2() {
  depends=('gtk2' 'xenocara-server')
  optdepends+=('gnome-themes-extra: default GTK+ theme')
  conflicts=('lxdm')
  provides=('lxdm-service')

  cd gtk2
  make DESTDIR="$pkgdir" install
  chmod 644 "$pkgdir/etc/lxdm/lxdm.conf"

  # install services
  install -Dm755 "$srcdir/lxdm.initd" "$pkgdir/etc/init.d/lxdm"
  install -Dm755 "$srcdir/lxdm.run" "$pkgdir/etc/sv/lxdm/run"

  # install license
  install -Dm644 gpl-2.0.txt -t "$pkgdir/usr/share/licenses/$pkgname"
}

package_lxdm() {
  pkgdesc+=' (GTK+ 3 version)'
  depends=('gtk' 'xenocara-server')
  conflicts=('lxdm-gtk2')
  provides=('lxdm-service')

  cd gtk3
  make DESTDIR="$pkgdir" install
  chmod 644 "$pkgdir/etc/lxdm/lxdm.conf"

  # install services
  install -Dm755 "$srcdir/lxdm.initd" "$pkgdir/etc/init.d/lxdm"
  install -Dm755 "$srcdir/lxdm.run" "$pkgdir/etc/sv/lxdm/run"

  # install license
  install -Dm644 gpl-2.0.txt -t "$pkgdir/usr/share/licenses/$pkgname"
}