# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=luakit
pkgver=2.2.1
_debver=2.2.1
_debrel=1
pkgrel=1
pkgdesc="Fast, small, webkit based browser framework extensible by Lua"
arch=('i686' 'x86_64')
url='https://luakit.github.io/'
license=('GPL-3')
depends=('lua51-filesystem' 'luajit' 'webkitgtk')
makedepends=('quilt' 'help2man')
backup=('etc/xdg/luakit/rc.lua'
        'etc/xdg/luakit/theme.lua')
source=(https://deb.debian.org/debian/pool/main/l/luakit/${pkgname}_${pkgver}.orig.tar.gz
        https://deb.debian.org/debian/pool/main/l/luakit/luakit_${_debver}-${_debrel}.debian.tar.xz
        libre.patch)
sha512sums=('9a055c1541f31027805d3da2604d98c0193a9c2874099fc3ab3ef08c645a8e91b8504d1162e86cbd29a5e5e0a3c54b3154299708f864d135d8640bcc3866674b'
            '886bd4eab3e5e841534518113824f0a18ddfcdd27f31652d1f926dd5acf864d1e28b40cc7bf219dd92a331983925b9d4ab733a1625ce5daad4d2988331526be1'
            '8c72a05473daa8a989fa2367d98112298e895f476bcf1538f97b9b9787e686bcba7b9f0e162ba400e2e10093475a09bfc869e5de52d5a0f55e290bdcb363420c')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # additional fixes to remove unfree references and content
  patch -Np1 -i ${srcdir}/libre.patch
}

build() {
  make DEVELOPMENT_PATHS=0 PREFIX=/usr USE_LUAJIT=1 -C ${pkgname}-${pkgver}
}

package() {
  make DESTDIR="${pkgdir}" PREFIX=/usr -C ${pkgname}-${pkgver} install
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/COPYING.GPLv3" -t "${pkgdir}/usr/share/licenses/$pkgname"
}