# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=luaexpat
pkgname=('lua-expat' 'lua51-expat' 'lua52-expat')
pkgver=1.3.0
_debver=1.3.0
_debrel=4
pkgrel=1
pkgdesc='SAX XML parser based on the Expat library'
arch=('i686' 'x86_64')
url='http://matthewwild.co.uk/projects/luaexpat/'
license=('Expat')
depends=('expat')
makedepends=('gcc' 'lua' 'lua51' 'lua52' 'quilt')
source=("https://deb.debian.org/debian/pool/main/l/lua-expat/lua-expat_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/l/lua-expat/lua-expat_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('4fe2455dfe73fca6b94e3e52e602980b44a44c30054fa4d830fe5627fb8dc23a887e21055e3db7c026366fae3b8240242f74ed9775bf6da212be5f752bf0caf8'
            'a03a1c6cf94bd40359bef8f15a2b5cbae31e3381bf75f181db22bcba58baa8160182fc642c068884001cd6ab548cece0cbf023d81f1ec6161159a83737ef9d93')

prepare() {
  mv lua-expat-$pkgver $pkgbase-$pkgver
  cd "$srcdir"/$pkgbase-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  cd ..
  cp -a $pkgbase-$pkgver $pkgbase-$pkgver-51
  cp -a $pkgbase-$pkgver $pkgbase-$pkgver-52
}

build() {
  # 5.1
  cd "$srcdir"/$pkgbase-$pkgver-51
  make LUA_V=5.1 COMMON_CFLAGS="$CPPFLAGS -fPIC"

  # 5.2
  cd "$srcdir"/$pkgbase-$pkgver-52
  make LUA_V=5.2 COMMON_CFLAGS="$CPPFLAGS -fPIC"

  # 5.3
  cd "$srcdir"/$pkgbase-$pkgver
  make LUA_V=5.3 COMMON_CFLAGS="$CPPFLAGS -fPIC"
}

package_lua51-expat() {
  replaces=('luaexpat')
  conflicts=('luaexpat')

  cd $pkgbase-$pkgver-51
  make LUA_V=5.1 DESTDIR="$pkgdir" install
  install -Dm0644 doc/us/license.html "$pkgdir/usr/share/licenses/$pkgname/license.html"
}

package_lua52-expat() {
  cd $pkgbase-$pkgver-52
  make LUA_V=5.2 DESTDIR="$pkgdir" install
  install -Dm0644 doc/us/license.html "$pkgdir/usr/share/licenses/$pkgname/license.html"
}

package_lua-expat() {
  cd $pkgbase-$pkgver
  make LUA_V=5.3 DESTDIR="$pkgdir" install
  install -Dm0644 doc/us/license.html "$pkgdir/usr/share/licenses/$pkgname/license.html"
}