# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=lua-dbi
_realpkgname=luadbi
pkgname=('lua51-dbi' 'lua52-dbi' 'lua-dbi')
pkgver=0.7.2
pkgrel=2
pkgdesc="Database interface library for Lua"
arch=('i686' 'x86_64')
url='https://github.com/mwild1/luadbi'
license=('Expat')
makedepends=('sqlite3' 'postgresql' 'lua' 'lua51' 'lua52')
optdepends=('sqlite3: sqlite3 Support'
            'postgresql-libs: postgresql Support')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/mwild1/luadbi/archive/v$pkgver.tar.gz"
        "remove-mariadb.patch")
sha512sums=('891f99cbc8f1b5327ef820641a1608abf41410f2f28584b975cc3cf65154b9bebf6f1b9ca7d1818b9c965738ad700dd17ae042dfd2a7146cf755871ebae535b9'
            '53811c430a647228981fcc07e02c79bf122824d4db61543b5add7893e5b9b24e2abc55a23d0e825d97ac952a57b15de6e80328795a9b1735e65633f1baf32e85')

prepare() {
  mv "$srcdir"/$_realpkgname-$pkgver "$srcdir"/$_realpkgname
  cd "$srcdir"/$_realpkgname
  patch -Np1 -i ${srcdir}/remove-mariadb.patch

  cp -r "$srcdir"/$_realpkgname "$srcdir"/$_realpkgname-51
  cp -r "$srcdir"/$_realpkgname "$srcdir"/$_realpkgname-52
}

build() {
  cd "$srcdir/$_realpkgname-51"
  make free LUA_V=5.1

  cd "$srcdir/$_realpkgname-52"
  make free LUA_V=5.2

  cd "$srcdir/$_realpkgname"
  make free LUA_V=5.3
}

package_lua51-dbi() {
  cd "$srcdir/$_realpkgname-51"
  make install_free DESTDIR="$pkgdir" LUA_V=5.1
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_lua52-dbi() {
  cd "$srcdir/$_realpkgname-52"
  make install_free DESTDIR="$pkgdir" LUA_V=5.2
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

package_lua-dbi() {
  cd "$srcdir/$_realpkgname"
  make install_free DESTDIR="$pkgdir" LUA_V=5.3
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}