# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lsof
pkgver=4.93.2
_debver=4.93.2
_debrel=dfsg-1.1
pkgrel=1
pkgdesc='Lists open files for running Unix processes'
url='https://github.com/lsof-org/lsof'
arch=('i686' 'x86_64')
license=('zlib')
depends=('glibc' 'libtirpc')
makedepends=('quilt')
source=(https://github.com/lsof-org/lsof/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/l/lsof/lsof_$_debver+$_debrel.debian.tar.xz
        license.txt)
sha512sums=('3c4a4d503391b1a648a08a4947c2e72a9629b169eddf50738b16a16a82f2a26967e4db2902e4a9157de5a73ae638db48e392117ffbd591e9fafd6b1725cd01a0'
            '9106067582de54d7dda83a72fc58fd98efeecd35ed938682d4b92341593e6fda7c7d4fe73ba4d5dbdf2077b3e8de52528cb64760d2813fc839edfc8b6b2227d4'
            '3bdbc8f213e9bdba946636498d21486e2b79d8ae44a45b284b4dff8875e76f992ab0977e3ed510525a8f74203028acb6b15315fda963666012874be4ce4fdd93')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  sed -i 's|/\* #define\tHASSECURITY\t1 \*/|#define\tHASSECURITY\t1|' dialects/linux/machine.h
  sed -i "s|.so ./version|.ds VN ${pkgver}|" -i Lsof.8
}

build() {
  cd ${pkgname}-${pkgver}

  ./Configure -n linux
  make CC="cc ${CFLAGS} ${CPPFLAGS} ${LDFLAGS}"
}

package() {
  cd ${pkgname}-${pkgver}

  install -Dm 755 lsof -t "${pkgdir}"/usr/bin
  install -Dm 644 Lsof.8 "${pkgdir}"/usr/share/man/man8/lsof.8
  install -Dm 644 "${srcdir}"/license.txt \
       "${pkgdir}"/usr/share/licenses/lsof/license.txt
}