# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lmms
pkgver=1.2.2
_debver=$pkgver
_debrel=2
pkgrel=3
pkgdesc="Free, libre and sophisticated digital audio workstation"
arch=('i686' 'x86_64')
url='https://lmms.io/'
license=('GPL-2')
depends=('alsa-lib' 'fftw' 'fltk' 'fluidsynth' 'freetype2' 'jack' 'ladspa' 'lame' 'libgig' 'libogg' 'libsamplerate'
         'libsndfile' 'libsndio' 'libvorbis' 'libx11' 'libxcb' 'portaudio' 'qt-x11extras' 'sdl' 'sndio' 'stk' 'zlib')
makedepends=('doxygen' 'extra-cmake-modules' 'qt-tools' 'quilt')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/l/${pkgname}/${pkgname}_${_debver}+dfsg1.orig.tar.xz"
	"https://deb.debian.org/debian/pool/main/l/${pkgname}/${pkgname}_${_debver}+dfsg1-${_debrel}.debian.tar.xz"
	"remove_leftover_entries_containing_nonlibre_demo_files.patch")
sha512sums=('fbb8cc46c5a0c167beb1e0eabb2790cf4d466349ef3ebf2463f99dd57b0cf0a0c73e354a8ef68bfbac4112875148495f53b4d388c2846065c35ed0dc0a4f4cac'
	    '2ba45643cf41eff1da741c5ddb1edc8532247587c6d32dfa986ac0a290a9ad55217b95d0391868356c9fab10aa878cd40b8ecf7dc1ef75c277c254c99d85ab74'
	    'f955f8434d099af32af827dac1e52f9cfebda99ae2abaee765d1301a3222b68b02da1dc6f1ffeeb44038a0a32b2124a67862a3e6822ac2c148f3de932528265a')

prepare() {
  mv -v ${pkgname}{,-${pkgver}}
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS="-p ab --no-timestamps --no-index"
    export QUILT_DIFF_ARGS="--no-timestamps"

    # remove old Debian source directory
    rm -frv debian || true

    cp -rv ${srcdir}/debian .

    # Doesn't apply
    rm -v debian/patches/add_keywords_to_the_desktop_file.patch || true

    quilt push -av
  fi

  # add keywords into a desktop shortcut file
  echo "Keywords=Audio;MIDI;Multitrack;Sequencer;DAW;ALSA;JACK;LADSPA;VST;Qt;" >> cmake/linux/lmms.desktop

  # apply patch removing few leftover entries containing project files under non-libre licenses from the licenses list
  patch -p1 -i ${srcdir}/remove_leftover_entries_containing_nonlibre_demo_files.patch

  # disable ZynAddSubFX plugin due to building issue
  sed -ie 'N;s#^\t*zynaddsubfx\n##' plugins/CMakeLists.txt
}

build() {
  cmake \
    -S ${pkgname}-${pkgver} \
    -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DCONTRIBUTORS="${PWD}/doc/CONTRIBUTORS" \
    -DCMAKE_MODULE_PATH=/usr/share/ECM/find-modules \
    -DCMAKE_BUILD_TYPE='None' \
    -DWANT_QT5=ON \
    -DWANT_PULSEAUDIO=OFF \
    -DWANT_SOUNDIO=OFF \
    -DWANT_SNDIO=ON \
    -DWANT_CARLA=OFF \
    -DOpenGL_GL_PREFERENCE=GLVND \
    -Wno-dev
  CXXFLAGS="${CXXFLAGS} -flto" LDFLAGS="${CXXFLAGS} ${LDFLAGS}" make -C build
}

package() {
  make DESTDIR=${pkgdir} install -C build
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/LICENSE.txt" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}