# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lighttpd
pkgver=1.4.69
pkgrel=2
pkgdesc="A secure, fast, compliant and very flexible web-server"
license=('Modified-BSD')
arch=('i686' 'x86_64')
url='https://www.lighttpd.net/'
depends=('pcre' 'util-linux' 'libressl' 'pcre2' 'gawk')
makedepends=('lua' 'libxml2' 'e2fsprogs' 'sqlite' 'gdbm' 'pkgconfig')
optdepends=('libxml2: mod_webdav'
            'lua: mod_cml/mod_magnet'
            'sqlite: mod_webdav')
backup=('etc/lighttpd/lighttpd.conf'
        'etc/logrotate.d/lighttpd')
options=('emptydirs')
source=("https://download.lighttpd.net/lighttpd/releases-1.4.x/lighttpd-${pkgver}.tar.xz"
        "lighttpd.conf"
        "lighttpd.logrotate.d"
        "lighttpd.confd"
        "lighttpd.initd"
        "lighttpd.run")
sha512sums=('9d174c8e0a192b4eb8218a9f76b0bd42f90030228600bb7bbe35ebb9e7bbaea36ee2732535c5cc6dab171294817837bfa26074ff84a37832dd89f57488b4071f'
            '7f832b5ec2171943624c6e592499b019e5425662fdb3e1b7418643bffdadb5245fbb9002063207413c53bd3f104b0d819565669c6911fd94e2727dd126382cdb'
            '92d0465ac8f459443226a086fa70fdce64fed6bfdab8b7d2f90b4c9db0a1af6d038906819ba8596fb4eb2dbfb165dfc1a170f37505c09f581493c1ea789029ee'
            'dd722c15230df734d7151bcb9cfc66d6d54aac5dcdca5f50eb33979d3a2443ba3a9ef3d7cb35e6dbd3d39fce09da15ab0029b1399bf1b1e4f4ef20d40f70a416'
            'd5fc03ded923d2aeea19fefdf658ed793114867dd0b50be6836d767108c98fb7de56011f00ea63220c4b198cff45d98fdc8a649efae90673536e03f786219485'
            '00e77e6cefd201de6c745547eecc9be6f3181331073921982f5d400139f2c1afe0dffc42a78082283cfdd21c79d59ec18ca5ce606f442b90b5c532cf62985e50')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  ./configure --prefix=/usr \
    --libdir=/usr/lib/lighttpd/ \
    --sysconfdir=/etc/lighttpd \
    --without-mysql \
    --with-ldap \
    --with-attr \
    --with-openssl \
    --with-kerberos5 \
    --without-fam \
    --with-webdav-props \
    --with-webdav-locks \
    --with-gdbm \
    --with-lua
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  install -D -m644 "$srcdir/lighttpd.logrotate.d" "$pkgdir/etc/logrotate.d/lighttpd"
  install -D -m644 "$srcdir/lighttpd.conf" "$pkgdir/etc/lighttpd/lighttpd.conf"

  install -d -m700 -o http -g http "$pkgdir"/var/{log,cache}/lighttpd/
  install -d -m700 -o http -g http "$pkgdir"/srv/http/

  install -Dm 644 "${srcdir}/lighttpd.confd" "${pkgdir}/etc/conf.d/lighttpd"
  install -Dm 755 "${srcdir}/lighttpd.initd" "${pkgdir}/etc/init.d/lighttpd"
  install -Dm 755 "$srcdir/lighttpd.run" "$pkgdir/etc/sv/lighttpd/run"

  pushd doc/config >/dev/null
  find . -type f ! -name 'Makefile*' -exec install -D -m644 {} "${pkgdir}"/usr/share/doc/lighttpd/config/{} \;
  popd >/dev/null

  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}