# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libzip
pkgver=1.7.3
_debver=$pkgver
_debrel=1.1
pkgrel=2
pkgdesc='A C library for reading, creating, and modifying zip archives'
url='https://libzip.org'
license=('Modified-BSD')
arch=('i686' 'x86_64')
depends=('zlib' 'bzip2' 'libressl' 'gnutls')
makedepends=('cmake' 'quilt')
source=("https://libzip.org/download/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/libz/libzip/libzip_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('488866348a0c859f6f995c50e956bd51b4105278f07b63fe019cb44ab36c09ef958cc0684fd5444c474d83874b999e8ed1aa9b2da51b74caa37bbe7934b9c870'
            'ca39b499e3a4af5ac61f0113bb0a611b9bfe79339de8aff83b7056543db3f4b3f5b178f58dd76de2f3f4888c619defbf5f5ec85126049d4eaf2ee8b775e340f3')

prepare() {
  cd "${pkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${pkgver}"

  cmake -Bbuild -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    .
  make -C build
}

package() {
  cd "${pkgname}-${pkgver}"

  make -C build DESTDIR="${pkgdir}" install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}