# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libytnef
pkgver=1.9.3
_debver=1.9.3
_debrel=3
pkgrel=1
epoch=1
pkgdesc="Yerase's TNEF Stream Reader library (decodes winmail.dat)"
url='https://github.com/Yeraze/ytnef'
license=('GPL-2')
arch=('i686' 'x86_64')
depends=('glibc')
makedepends=('perl' 'quilt')
optdepends=('perl: ytnefprocess')
source=("https://deb.debian.org/debian/pool/main/liby/libytnef/${pkgname}_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/liby/libytnef/libytnef_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('be0a46e79561a5ff34f812b892a781809606cc7e38c6bfed15bae7773f952b4b55aed0fa784922e72839121672c540496db1bac602630c5a83141f8517a4a543'
            '2a50ed17f5d05c4c033f87e9dc84ebac201fc83502f6ead87a1b16c39c37504026d8132e856ef9f5c60f53b9a06da58a49be2207436ebac68fb0eaa163b771b5')

prepare() {
  cd ytnef-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  ./autogen.sh
}

build() {
  cd ytnef-${pkgver}

  ./configure --prefix=/usr --disable-static
  make
}

package() {
  cd ytnef-${pkgver}

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/$pkgname
}