# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libxslt
pkgver=1.1.34
_debver=1.1.34
_debrel=4
pkgrel=2
pkgdesc="XML stylesheet transformation library"
url="http://xmlsoft.org/XSLT/"
arch=(i686 x86_64)
license=(Expat)
depends=(libxml2 libgcrypt)
makedepends=(tauthon quilt)
checkdepends=(docbook-xml python)
source=(ftp://xmlsoft.org/libxslt/libxslt-$pkgver.tar.gz{,.asc}
        https://deb.debian.org/debian/pool/main/libx/libxslt/libxslt_$_debver-$_debrel.debian.tar.xz)
validpgpkeys=('C74415BA7C9C7F78F02E1DC34606B8A5DE95BC1F') # Daniel Veillard
sha512sums=('1516a11ad608b04740674060d2c5d733b88889de5e413b9a4e8bf8d1a90d712149df6d2b1345b615f529d7c7d3fa6dae12e544da828b39c7d415e54c0ee0776b'
            'SKIP'
            'dbd4104503a3eee856bf42c0a55e78de3687578498c4ab6dac889e787997a1a2fc9d95a0ea7acee37fa6e31e3f79bd791a176eb2f616fa5a8886008fe87b53ce')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/0003-remove-plugin-in-xslt-config.patch || true
    rm -v debian/patches/0004-do-not-clean-manpage.patch || true

    quilt push -av
  fi

  sed -e 's|/usr/bin/python -u|/usr/bin/tauthon -u|g' \
      -e 's|/usr/bin/python$|/usr/bin/tauthon|g' \
      -i python/tests/*.py

  autoreconf -vfi
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --with-python=/usr/bin/tauthon
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  find "$pkgdir" -name '*.a' -print -delete
}