# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libxmp
pkgver=4.4.1
_debver=4.4.1
_debrel=3
pkgrel=1
pkgdesc='Library that supports many module-formats'
arch=('i686' 'x86_64')
url='https://xmp.sourceforge.net/'
license=('LGPL-2.1')
depends=('glibc')
makedepends=('quilt')
options=(!emptydirs)
source=("https://download.sourceforge.net/project/xmp/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libx/libxmp/libxmp_$_debver-$_debrel.debian.tar.xz")
sha512sums=('81608b60f9b952ae4899854235c99493f0acb9e79254143037f7f5b8d368a0149d52e5c32cd4fd07882d02897f801bac3f7e27d6dd20ba9f6106534f54ab1cf6'
            '35f8651ea61dca0792b92eed13dcb5e7c0def4279557da0501b9cf0b6bd4c7b4eca1c59249a9fb28dba38d45378f8260540e36cd994f32dee7c7a98765a18270')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  CFLAGS="$CFLAGS -fno-lto"
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir/" install
  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/docs/COPYING.LIB" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}